Letzte Änderung: 08.01.2023
Excel Logo hb
Syntax:
=ZÄHLENWENN(Bereich; Suchkriterium)

Die Funktion ZÄHLENWENN geht den angegebenen Bereich durch und zählt alle Zellen, für die das Suchkriterium zutreffend ist.

Beispiel 1

Formel in der Zelle G5:
=ZÄHLENWENN($C$4:$C$23;G4)

Bereich: $C$4:$C$23
Suchkriterium: G4

Im einfachsten Fall kann ein Aufruf der Funktion so aussehen: =ZÄHLENWENN($C$4:$C$23;"BPD-4"). Damit wird gezählt, wie oft die Produktnummer "BPD-4" in der Liste vorkommt. In der hier verwendeten Formel wird jedoch die Produktnummer aus der Zelle G4 gelesen. Das Produkt "BPD-4" steht dreimal in der Liste, ist also dreimal verkauft worden.

Zum Ausprobieren:

 

Weitere Möglichkeiten für Aufrufe der Funktion ZÄHLENWENN:

Wie viele Mitarbeiternamen beginnen mit "S"?
Formel:   =ZÄHLENWENN($B$4:$B$23;"S*")
Sog. Wildcards wie "*" und "?" können beim Suchkriterium verwendet werden.

Wie viele Verkäufe lagen in der zweiten Jahreshälfte?
Formel:   =ZÄHLENWENN($D$4:$D$23;">=1.7.2022")
Hier wird in der Spalte D gesucht.
Vor dem eigentlichen Suchbegriff können auch Vergleichsoperatoren stehen wie ">", ">=", usw.

Beispiel 2

Dieses Beispiel ist schon etwas komplexer und zeigt das Zusammenwirken der Funktionen ZÄHLENWENN, INDEX und VERGLEICH, um die Liste der Mitarbeiter zu sortieren.

In der Spalte C ermittelt die ZÄHLENWENN-Funktion zunächst die Position jedes einzelnen Namens in der alphabetischen Liste. In der Spalte D kommt dann die Kombination der Funktionen INDEX und VERGLEICH zum Einsatz, um aus der Zahlenliste die sortierte Namensliste zu generieren.

Die Spalte C ist nur eine Hilfsspalte mit Zwischenergebnissen, die in der Praxis normalerweise ausgeblendet wird.

 

Formel in der Zelle C4:
=ZÄHLENWENN($B$4:$B$15;"<="&B4)

Bereich: $B$4:$B$15
Suchkriterium: "<="&B4

Im Suchkriterium wird das Zeichen & verwendet, um zwei Zeichenketten (Textabschnitte) aneinander zu hängen. Hier wird also die Zeichenkette ">=" mit dem Inhalt der Zelle B4 zu einer Zeichenkette verbunden. Das Suchkriterium lautet somit ">=Becker". Wenn diese Formel nach unten kopiert wird, wird aus dem ">="&B4 in der nächsten Zeile ">="&B5, in der übernächsten ">="&B6 usw.

Für jeden Namen wird gezählt, wie viele Namen in der Liste kleiner oder gleich dem eigenen Namen sind. Beispielsweise sind das für den Namen "Becker" der Name "Baumgarten" und der Name "Becker" selbst. Deshalb erscheint in Zelle C4 eine 2. Für den Namen "Lehmann" sind es die Namen "Baumgarten", "Becker", "Fischer", "Lange" und "Lehmann" selbst. Deshalb steht in Zelle C5 eine 5.

Formel in der Zelle D4:
=INDEX($B$4:$B$15;VERGLEICH(ZEILE(A1);$C$4:$C$15;0))

Die Kombination der beiden Funktionen INDEX und VERGLEICH wird im Beispiel 2 zur Funktion INDEX ausführlich erklärt. Die innere Funktion VERGLEICH hat als ersten Parameter den Funktionsaufruf ZEILE(A1). Die Funktion ZEILE gibt die Zeilennummer der Zelle A1 zurück, also die 1. Da beim Kopieren der Formel nach unten in der zweiten Zeile aus A1 ein A2 wird, in der dritten Zeile ein A3 usw., sucht die Funktion VERGLEICH in der ersten Zeile nach der Zahl 1, in der zweiten Zeile nach der Zahl 2, in der dritten Zeile nach der Zahl 3 usw.

Die VERGLEICH-Funktion findet die Zahl 1 an der 8. Position in der Spalte C und übergibt die Zahl 8 an die INDEX-Funktion, welche in der Namensliste (in Spalte B) den Namen 'Baumgarten' an der 8. Position findet. In der zweiten Zeile findet die VERGLEICH-Funktion die Zahl 2 an der 1. Position (in Spalte C) und gibt die Zahl 1 an die INDEX-Funktion weiter. Die INDEX-Funktion findet an der 1. Position in Spalte B den Namen 'Becker' und trägt ihn in der zweiten Zeile in die sortierte Liste ein. Entsprechendes passiert in den restlichen Zeilen.

Das Suchkriterium kann eine Zahl, eine Zeichenfolge (Text in Anführungszeichen), ein Vergleich wie z. B. ">=1000" oder ein Zellbezug wie z. B. D5 sein.
Die ZÄHLENWENN-Funktion ignoriert leere Zellen. Deshalb kann man mit der Formel =ZÄHLENWENN(A1:A9;"*") zählen, wie viele nicht-leere Zellen im Bereich A1:A9 vorkommen.